Автоматизация сборки с помощью py2exe

Думаю, все питонщики знакомы с py2exe, позволяющем создавать exe для Windows. Однако работа с этим инструментом не тривиальна, так что уже довольно давно для самых простых задач (других с помощью питона мне решать пока не приходилось) имеется у меня батник, позволяющий за одно движение мыши превратить файл консольного приложения на Python в exe'шник. Конечно, возможности py2exe этим не ограничиваются, однако лично мне этого хватает, да и познания в bat'нике не велики.

@echo off
rem PY2EXE executable builder

if "%1" == "" (
    echo Using: buildexe entry_point_path [-noopt]
    echo entry_point_path     - path to the .py file that contains program entry point
    echo -noopt             - disable Python compiler optimization
    
    goto END
)

set DRIVE=%~d1
set OUTDIR=%~dp1
set OPTIONS=-OO

rem Disabling optimization
if "%2" == "-noopt" (
    set OPTIONS=
)

%DRIVE%
cd %OUTDIR%

rem Creating setup file for PY2EXE
echo # setup.py                                      > setup.py
echo from distutils.core import setup                 >> setup.py
echo import py2exe                                     >> setup.py
echo setup(options = {"py2exe": {                     >> setup.py
echo     "bundle_files": 1,                             >> setup.py
echo     "optimize": 2,                                 >> setup.py
echo     "dist_dir": "bin"}},                         >> setup.py
echo     zipfile = "lib.zip",                         >> setup.py
echo     console = ["%~n1.py"])                         >> setup.py

rem Creating bat-file for rebuilding manually
echo @echo off                                          > rebuild.bat
echo rem Made by 'PY2EXE executable builder'.         >> rebuild.bat
echo %DRIVE%                                         >> rebuild.bat
echo cd %OUTDIR%                                    >> rebuild.bat
echo %~dp0python %OPTIONS% setup.py py2exe             >> rebuild.bat

rem Calling PY2EXE
%~dp0python %OPTIONS% setup.py py2exe

:END

Для запуска нужно только перетащить в Проводнике файл .py на этот батник, после чего в папке с .py появятся:

• rebuild.bat - батник для пересборки



• setup.py - проект py2exe (что-то вроде build.xml для Ant, код на Python вообще вещь универсальная, достаточно посмотреть на питоновские ORM, где схема БД описывается... кодом на Python. Привет, Hibernate! :))



• \bin - папка, содержащая выходные даннные



• \build - папка с зависимостями, для дистрибуции не нужна